<!--
	Copyright (c) 2007 Martin Junghans, Dirk Riehle, SAP Labs LLC. 
	Taken from: Martin Junghans, Dirk Riehle, and Umit Yalcinalp. 
	An XML interchange format for Wiki Creole 1.0 
	In ACM SIGWEB Newsletter, Volume 2007, 
	Issue Winter (Winter 2007), Article No. 5.
-->

<?xml version="1.0" encoding="UTF-8"?>
<xsl:transform version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:WikiCreole="http://www.wikicreole.org/ns/creole">
	<xsl:output method="text" encoding="UTF-8" indent="yes"/>

	<xsl:template match="WikiCreole:wikipage">
		<xsl:variable name="wpName" select="@name"/>
		<xsl:result-document href="{$wpName}">
			<xsl:apply-templates/>
		</xsl:result-document>
	</xsl:template>

	<xsl:template match="WikiCreole:textparagraph">
		<xsl:apply-templates/>
		<!-- one blank line (two linefeeds) after a paragraph 
		as paragraph separator: -->
		<xsl:text>

</xsl:text>
	</xsl:template>

	<xsl:template match="WikiCreole:bold">
		<xsl:text>**</xsl:text>
		<xsl:apply-templates/>
		<xsl:text>**</xsl:text>
	</xsl:template>

	<xsl:template match="WikiCreole:italic">
		<xsl:text>//</xsl:text>
		<xsl:apply-templates/>
		<xsl:text>//</xsl:text>
	</xsl:template>

	<xsl:template match="WikiCreole:nowiki">
		<xsl:text>{{{</xsl:text>
		<xsl:apply-templates/>
		<xsl:text>}}}</xsl:text>
	</xsl:template>

	<xsl:template match="WikiCreole:textlinebreak">
		<xsl:text>\\</xsl:text>
	</xsl:template>

	<xsl:template match="WikiCreole:heading">
		<xsl:variable name="level" select="@level"/>
		<xsl:call-template name="heading_markup">
			<xsl:with-param name="level" select="$level"/>
		</xsl:call-template>
		<xsl:apply-templates/>
		<xsl:call-template name="heading_markup">
			<xsl:with-param name="level" select="$level"/>
		</xsl:call-template>
		<xsl:text>

</xsl:text>
	</xsl:template>

	<xsl:template name="heading_markup">
		<xsl:param name="level" select="1"/>
		<xsl:if test="$level > 0">
			<xsl:text>=</xsl:text>
			<xsl:call-template name="heading_markup">
				<xsl:with-param name="level" select="$level - 1"/>
			</xsl:call-template>
		</xsl:if>
	</xsl:template>

	<xsl:template match="WikiCreole:orderedlist">
		<xsl:call-template name="oList">
			<xsl:with-param name="listlevel" select="string('#')"/>
		</xsl:call-template>
				<xsl:text>
</xsl:text>
	</xsl:template>

	<xsl:template match="WikiCreole:unorderedlist">
		<xsl:call-template name="uList">
			<xsl:with-param name="listlevel" select="string('*')"/>
		</xsl:call-template>
		<xsl:text>
</xsl:text>
	</xsl:template>

	<xsl:template name="uList">
		<xsl:param name="listlevel"/>
		<xsl:for-each select="WikiCreole:listelem | WikiCreole:orderedlist | WikiCreole:unorderedlist">
			<xsl:variable name="type" select="local-name()"/>
			<xsl:if test="$type='listelem'">
				<xsl:value-of select="$listlevel"/>
				<xsl:apply-templates/>
				<xsl:text>
</xsl:text>
			</xsl:if>
			<xsl:if test="$type='orderedlist'">
				<xsl:call-template name="oList">
					<xsl:with-param name="listlevel" select="concat($listlevel, '#')"/>
				</xsl:call-template>
			</xsl:if>
			<xsl:if test="$type='unorderedlist'">
				<xsl:call-template name="uList">
					<xsl:with-param name="listlevel" select="concat($listlevel, '*')"/>
				</xsl:call-template>
			</xsl:if>
		</xsl:for-each>
	</xsl:template>

	<xsl:template name="oList">
		<xsl:param name="listlevel"/>
		<xsl:for-each select="WikiCreole:listelem | WikiCreole:orderedlist | WikiCreole:unorderedlist">
			<xsl:variable name="type" select="local-name()"/>
			<xsl:if test="$type='listelem'">
				<xsl:value-of select="$listlevel"/>
				<xsl:apply-templates/>
				<xsl:text>
</xsl:text>
			</xsl:if>
			<xsl:if test="$type='orderedlist'">
				<xsl:call-template name="oList">
					<xsl:with-param name="listlevel" select="concat($listlevel, '#')"/>
				</xsl:call-template>
			</xsl:if>
			<xsl:if test="$type='unorderedlist'">
				<xsl:call-template name="uList">
					<xsl:with-param name="listlevel" select="concat($listlevel, '*')"/>
				</xsl:call-template>
			</xsl:if>
		</xsl:for-each>
	</xsl:template>

	<xsl:template match="WikiCreole:listelem">
		<xsl:apply-templates/>
		<xsl:text>
</xsl:text>
	</xsl:template>

	<xsl:template match="WikiCreole:table">
		<xsl:apply-templates/>
		<xsl:text>

</xsl:text>
	</xsl:template>

	<xsl:template match="WikiCreole:tablerow">
		<xsl:apply-templates/>
		<xsl:text>|
</xsl:text>
	</xsl:template>

	<xsl:template match="WikiCreole:tablecell">
		<xsl:variable name="header" select="@header"/>
		<xsl:if test="$header = boolean(1)">
			<xsl:text>|=</xsl:text>
			<xsl:apply-templates/>
		</xsl:if>
		<xsl:if test="$header = boolean(0)">
			<xsl:text>|=</xsl:text>
			<xsl:apply-templates/>
		</xsl:if>
	</xsl:template>

	<xsl:template match="WikiCreole:nowikiblock">
		<xsl:text>{{{
</xsl:text>
		<xsl:apply-templates/>
		<xsl:text>
}}}

</xsl:text>
	</xsl:template>

	<xsl:template match="WikiCreole:horizontalrule">
		<xsl:text>----

</xsl:text>
	</xsl:template>

	<xsl:template match="WikiCreole:link">
		<xsl:variable name="uri" select="WikiCreole:uri"/>
		<xsl:variable name="description" select="WikiCreole:description"/>
		<xsl:text>[[</xsl:text>
		<xsl:value-of select="$uri"/>
		<xsl:if test="string-length($description) > 0">
			<xsl:text>|</xsl:text>
			<xsl:apply-templates select="$description"/>
		</xsl:if>
		<xsl:text>]]</xsl:text>
	</xsl:template>

	<xsl:template match="WikiCreole:image">
		<xsl:variable name="uri" select="WikiCreole:uri"/>
		<xsl:variable name="alternative" select="WikiCreole:alternative"/>
		<xsl:text>{{</xsl:text>
		<xsl:apply-templates select="$uri"/>
		<xsl:if test="string-length($alternative) > 0">
			<xsl:text>|</xsl:text>
			<xsl:apply-templates select="$alternative"/>
		</xsl:if>
		<xsl:text>}}</xsl:text>
	</xsl:template>

	<xsl:template match="WikiCreole:extension">
		<xsl:variable name="handler" select="@handler"/>
		<xsl:text>@@</xsl:text>
		<xsl:value-of select="$handler"/>
		<xsl:text> </xsl:text>
		<xsl:apply-templates/>
		<xsl:text>@@</xsl:text>
	</xsl:template>
</xsl:transform>